Listing 1:

<!---
	This code is a modified version of the javaRB.cfc by Paul Hastings.
	You can find the original code + examples here: 
	
	http://www.sustainablegis.com/unicode/resourceBundle/javaRB.cfm
--->

<cfcomponent displayname="resourceBundle" hint="Reads and parses resource 
  bundle per locale" output="false">
	
	<cfscript>
	variables.rB = createObject("java", 
	 "java.util.PropertyResourceBundle");
	variables.fis = CreateObject("java", "java.io.FileInputStream"); 
	</cfscript>

	<cffunction name="getResource" access="public" output="false" 
	  returnType="string" hint="Returns bundle.X, if it exists, and 
	  optionally wraps it in ** if debug mode.">
		<cfargument name="resource" type="string" required="true">
		<cfargument name="rbFile" type="string" required="false">
		<cfargument name="rbLocale" type="string" required="false" 
		  default="en_US">

		<cfset var val = "">
		<cfset var rb = "">
		
		<!--- If passed a file name for the RB, load it. --->
		<cfif isDefined("arguments.rbFile")>
			<cfset rb = getResourceBundle(arguments.rbFile,
			 arguments.rbLocale)>
		<!--- else, they MUST have used loadRB() --->
		<cfelseif not isDefined("variables.resourceBundle")>
			<cfthrow message="Fatal Error: Resource bundle file 
			  must be passed to this method if loadResourceBundle is not used.">
		<cfelse>
			<cfset rb = variables.resourceBundle>
		</cfif> 
		

		<cfif not structKeyExists(rb, arguments.resource)>
			<cfset val = "">
		<cfelse>
			<cfset val = rb[arguments.resource]>
		</cfif>

		<cfif isDebugMode()>
			<cfset val = "*** #val# ***">
		</cfif>
		
		<cfreturn val>
		
	</cffunction>
	
	<cffunction name="getResourceBundle" access="public" output="false" 
	  returntype="struct" hint="Reads the RB into a struct">
		<cfargument name="rbFile" required="true" type="string" 
		  hint="The file name of the bundle.">
		<cfargument name="rbLocale" required="false" type="string" 
		  default="en_US">

		<cfset var resourceBundle = structNew()>
		<cfset var thisRBFile = "">
		<cfset var keys = "">
		<cfset var thisKey = "">
		<cfset var thisVal = "">
		
		<!--- Translate rbFile if it does not exist --->
		<cfif not fileExists(arguments.rbFile)> 
			<!--- Try to change X.FOO to X_#argumentslocale#.FOO 
			--->
			<cfset thisRBFile = getFileFromPath(arguments.rbFile)>
			<cfset thisRBfile = getDirectoryFromPath(arguments.rbFile) &
			listFirst(thisRBfile,".") & "_" & arguments.rbLocale & "." &
			listLast(thisRBfile,".")>
			<cfif not fileExists(thisRBFile)>
				<cfthrow message="Fatal Error: Resource 
				  bundle file (#thisRBFile#) not found.">
			<cfelse>
				<cfset arguments.rbFile = thisRBFile>
			</cfif>
		</cfif> 
				
		<cfscript>
		variables.fis.init(arguments.rbFile);
		variables.rB.init(variables.fis);
		keys=variables.rB.getKeys();
		while (keys.hasMoreElements()) {
			thisKey=keys.nextElement();
			thisVal=rB.handleGetObject(thisKey);
			resourceBundle[thisKey]=thisVal;
		}
		fis.close();
		</cfscript>
				
		<cfreturn resourceBundle>
		
	</cffunction> 
	
	<cffunction name="loadResourceBundle" access="public" output="false" 
	  returnType="void" hint="Loads a bundle for the persisted CFC">
		<cfargument name="rbFile" required="true" type="string">
		<cfargument name="rbLocale" required="false" type="string" 
		  default="en_US">
		
		<cfset variables.resourceBundle = 
		  getResourceBundle(arguments.rbFile,arguments.rbLocale)>
	</cffunction>
	
</cfcomponent>

Listing 2:

<cfinvoke component="resourcebundle" method="getResourceBundle" 
  returnVariable="bundle">
	<cfinvokeargument name="rbFile" value="#expandPath("./testJavaRB.
	  properties")#">
	<cfinvokeargument name="rbLocale" value="fr_FR">
</cfinvoke>

<form>
<cfoutput><input type="submit" value="#bundle.save#"> <input type="reset" 
  value="#bundle.cancel#"></cfoutput>
</form>

Listing 3:

<cfapplication name="rbDemo" sessionmanagement="true">

<cfparam name="session.locale" default="en_US">

<cfif isDefined("form.newlocale")>
	<cfset session.locale = form.newlocale>
</cfif>

<cfif not isDefined("application.localeBundles")>
	<cfset application.localeBundles = structNew()>
</cfif>

<cfif not structKeyExists(application.localeBundles, session.locale)>
	<cfinvoke component="resourcebundle" method="getResourceBundle" 
	  returnVariable="bundle">
		<cfinvokeargument name="rbFile" 
		  value="#expandPath("./testJavaRB.properties")#">
		<cfinvokeargument name="rbLocale" value="#session.locale#">
	</cfinvoke>
	<cfset application.localeBundles[session.locale] = duplicate(bundle)>
<cfelse>
	<cfset bundle = application.localeBundles[session.locale]>
</cfif>

<cfoutput>
<form action="#cgi.script_name#" method="post">
<select name="newlocale">
	<option value="en_US" <cfif session.locale is 
	  "en_US">selected</cfif>>English</option>
	<option value="fr_FR" <cfif session.locale is 
	  "fr_FR">selected</cfif>>French</option>
</select><br>
<input type="submit" value="#bundle.save#"> <input type="reset" 
  value="#bundle.cancel#">
</form>
</cfoutput>