Listing 1

<!--- Note that Ben Forta's Auto-Suggest Tutorial is at http://www.forta.com/blog/index.cfm/2007/5/31/ColdFusion-Ajax-Tutorial-1-AutoSuggest --->
<html>
<head>
<title>ColdFusion 8 Auto Suggest Example</title>
</head>
<body>
<h2>CF8 Auto Suggest Example</h2>
<CFFORM style="margin-left:10px; margin-top:10px;">
Search Art:
<!--- Populate autosuggest attribute with comma-delimited list of hard-coded values --->
<CFINPUT type="text" name="artname" autosuggest="1958,60 Vibe,Beauty,Bowl of
 Flowers,Charles,Christmas,Closed,Cowboy,Do it,Dude,Empty,Enchanted Tree,Freddy,Hang Ten,Happiness,Ideas,Leaning
  House,Life is a Horse,Man in Jeans,Man on Stool,Mary,Melon,Michael,Mom,Morning Forest,Morph,Mountains,Music,My
   Venus,Mystery,Naked,Paradise,Paulo,Pretty Life,Prize Fight,Singer,Sky,Slices of Life,Space,The
    Lake,Things,Toxic,Windy,Yellow to Me,You Don't Know Me">
</CFFORM>
</body>
</html>


Listing 2 for article "Test Driving the ColdFusion 8 Beta Release"

<!--- use <CFFEED> to retrieve EPA RSS 2.0 Air news feed as a CF query --->
<CFSET theURL = "http://yosemite.epa.gov/opa/admpress.nsf/RSSByCategory?open&category=Air">

<CFFEED action="read" properties="myProps" query="getRSS" source="#theURL#" />

<!--- if desired, use QoQ to retrieve a subset of the records from RSS news feed --->
<CFQUERY name="getFilteredRSS" dbtype="query">
<!--- use QoQ CAST function to convert PUBLISHEDDATE column values to dates  --->
SELECT TITLE, RSSLINK, CAST(PUBLISHEDDATE AS DATE) AS PUBDATE
FROM getRSS
<!--- retrieve only those records with 'EPA' in the title; this is a case-sensitive search --->
WHERE TITLE LIKE '%EPA%' 
</CFQUERY>

<html>
<head>
<title>CFFEED/HTML Data Grid Example</title>
</head>
<body>
<h3>EPA Air News Releases</h3>
<!--- load query data into a simple CF8 HTML datagrid for easy display --->
<CFFORM style="margin-left:10px; margin-top:10px;">
<CFGRID name="epaRSS" format="html" striperows="yes" query="getFilteredRSS" appendkey="no">
<CFGRIDCOLUMN name="title" header="Title" width="360" href="rsslink" />
<CFGRIDCOLUMN name="pubdate" header="Published Date" width="170" />
<CFGRIDCOLUMN name="rsslink" display="no" />
</CFGRID>
</CFFORM>
</body>
</html>

<!--- to get detailed information about a feed, dump the value of the CFFEED tag's "properties" attribute  --->
<CFDUMP var="#myProps#">